/*=========================================================
Terza lezione di Pov Ray 21 Maggio 2010
Elisa Conversano
=========================================================*/
//includiamo i file .inc
#include "colors.inc" //colori
#include "textures.inc" //texture
//inserisco il punto di vista
camera {
location 1*<0,6,-4>
look_at <0,0,0>
angle 40
}
//inserisco le luci
light_source { <1,4,-2> color 1 }
light_source { <-1,2,-6> color 1 shadowless}
//tavolo d'appoggio
plane {y,0 texture {DMFWood1}}
//definisco la curva attraverso una macro
//argomento della macro è T
#macro Curva(T)
#local S = 3; // numero di spire
#local Phi = S*(2*pi*T); //angolo giro per il numero di spire
#local R = 1.5*T; //raggio in funzione di T
<R*cos(Phi),T,R*sin(Phi)> //descrizione della curva
#end
//disegno la curva attraverso un ciclo di palline
union {
#local Spessore = 0.03;
#local N = 1000;
#local I = 0;
#while (I < N)
#local T = I/(N-1); //T va da 0 a 1
#local P = Curva(T);
sphere { P, Spessore }
#local I = I + 1;
#end
texture {
pigment {Yellow}
finish {metallic}
}
}